Guilded Youth — 5 of 6

Section 4 (Objects)

Instead of taking inventory, say "You can see what you're carrying in the left column, and your current party members in the right column."

After taking something:

play mp3 sound file "[if player is ascii]joined.mp3[otherwise]treasuregetting.mp3[end if]";

refresh inventory illustrations;

continue the action.

Instead of giving something to someone, try showing the noun to the second noun.

Instead of dropping something enclosed by the player:

say "Your sticky fingeredness won't let you.";

stop the action.

The sword is scenery in the Adventurers' Lounge. "[if chris is in location]Chris['] sword glows green and true.[otherwise]You don't see that here."

The desk is scenery in the Study. The description of the desk is "The desk was probably too big to get out through the door, so they just left it there. All its drawers are missing. It’s a lovely old wooden specimen, however, and it saddens you it will be smashed to pieces in two days. As you run a fond hand over it, you notice a glint in the inkwell."

The inkwell is part of the desk. Understand "glint" as inkwell. The inkwell is a container. The letter opener is in the inkwell.

Before examining the inkwell:

if letter opener is in inkwell:

say "The glint you saw is from a letter opener. Your lithe fingers tease it out and Ryan crowds around. ‘Oooh, a dagger,’ he says. You reluctantly hand it over.

Ryan feels the edge and then scoffs. ‘Super-dull,’ he says, handing it back.

Your heart lightens and you don’t correct him. You secret it away for closer inspection later.";

move letter opener to player;

play mp3 sound file "treasuregetting.mp3";

stop the action;

otherwise:

say "Empty.";

stop the action.

The rope is scenery.

The bottle of white wine is a container. "There's a bottle of white wine with a dusty label, within arms' reach." Instead of opening wine, try drinking wine. The bottle of red wine is a container. "A bottle of red wine with a dusty label."

Instead of showing noun to second noun:

if second noun is Chris:

say "[if noun is map]Chris seems skeptical. 'Old houses are cool, but why bother?'[otherwise if noun is magazine]Chris the Paladin's silence is steely.[otherwise if noun is letter opener]'Yep, good find there kid,' says Chris.[otherwise if noun is pocket watch]Chris the Paladin winks at you. 'You keep that warm for me, teef.'[otherwise if noun is doorknob]Chris shrugs. 'Kind of neat, but it's less of an antique than a piece of a door.'[end if]";

if second noun is harry:

say "[if noun is map]'Why would you make a map of your own neighbourhood that's dumb' says Harry the Barbarian.[otherwise if noun is fork]'Yeah I was there when you scooped it remember?' says Harry the Barbarian.[otherwise if noun is letter opener]'Are you threatening me? hahahahahaha' says Harry the Barbarian.[otherwise if noun is pocket watch]'My grampa gave me one of those but you gotta wind it every day,' says Harry the Barbarian.[otherwise if noun is doorknob]'Why did you keep that? You gotta junk problem dude,' says Harry.[end if]";

if second noun is Ryan:

say "[if noun is fork]'If it's not a tuning fork, I can't use it,' quips Ryan the Bard.[otherwise if noun is magazine]'Dude are you crazy waving that thing around?' says Ryan the Bard.[otherwise if noun is letter opener]'Yeah I saw it in the house, did you sharpen it yet?' says Ryan the Bard.[otherwise if noun is pocket watch]'That's pretty sweet, but my mom would give me the fifth if she saw it,' says Ryan the Bard.[otherwise if noun is map]'I know the way to the Manor, dude!' says Ryan the Bard.[end if]";

if second noun is Maximus:

say "[if noun is fork]'Are you stooping to stealing cutlery now?' says Maximus the Cleric.[otherwise if noun is magazine]You don't dare. You'd be kicked from the Guild for sure.[otherwise if noun is letter opener]'You're lucky I know that's not a weapon,' says Maximus the Cleric.[otherwise if noun is map]'Please do not attempt to conspire with me,' says Maximus the Cleric.[otherwise if noun is doorknob]'Are you saying somewhere someone's trapped inside a room with no hope of escape? Much like you in the afterworld, if you fail to repent,' says Maximus the Cleric.[end if]";

if second noun is Paula:

say "[if noun is pocket watch]'I already know what time it is, sweety,' says Paula the Mage.[otherwise if noun is magazine]'Oh my, aren't you a naughty little boy,' says Paula the Mage.[otherwise if noun is fork]'Doesn't match my other cutlery,' says Paula the Mage. 'But thanks anyway, sweetie.'[otherwise if noun is map]'A heist seems exciting, but not tonight,' says Paula the Mage.[otherwise if noun is doorknob]'My castle's already fully decorated,' says Paula the Mage.[end if]".

Instead of showing map to Ryan during Online:

now ryan is joined;

clear avatar illustrations;

refresh avatar illustrations;

say "'I'm in!' Ryan whispers. 'It's now or never for the old Manor!'[paragraph break][bold type]***Ryan the Bard has joined your party.***[roman type][paragraph break]";

play mp3 sound file "joined.mp3";

move map to Ryan;

refresh inventory illustrations.

Instead of showing magazine to Harry:

move magazine to Harry;

now Harry is joined;

play mp3 sound file "joined.mp3";

clear avatar illustrations;

refresh inventory illustrations;

refresh avatar illustrations;

say "'where did you get this?' whispers Harry. 'this is awesome!'[paragraph break]You explain the Manor and the potential treasures within, if only you had a companion strong enough to breach the gate...[paragraph break][bold type]***Harry the Barbarian has joined your party.***[roman type][paragraph break]".

Instead of showing doorknob to Ryan:

move doorknob to Ryan;

now Ryan is joined;

play mp3 sound file "joined.mp3";

clear avatar illustrations;

refresh avatar illustrations;

refresh inventory illustrations;

say "‘Cool loot,’ whispers Ryan. He agrees to meet you at your place later tonight. [paragraph break][bold type]***Ryan the Bard has joined your party.***[roman type]".

Instead of showing fork to Chris:

move fork to Chris;

now Chris is joined;

play mp3 sound file "joined.mp3";

clear avatar illustrations;

refresh avatar illustrations;

refresh inventory illustrations;

say "‘Sounds like Victorian cutlery,’ Chris whispers. Chris agrees to meet you at the Manor later tonight. [paragraph break][bold type]***Chris the Paladin has joined your party.***[roman type][paragraph break]".

Instead of showing letter opener to Paula:

move letter opener to Paula;

now Paula is joined;

play mp3 sound file "joined.mp3";

clear avatar illustrations;

refresh avatar illustrations;

refresh inventory illustrations;

say "'Ooh, pretty pretty...’ she says. Paula agrees to join your raiding party.[paragraph break][bold type]***Paula the Mage has joined your party.***[roman type][paragraph break]".

Instead of showing watch to Maximus:

move watch to Maximus;

now Maximus is joined;

play mp3 sound file "joined.mp3";

clear avatar illustrations;

refresh avatar illustrations;

refresh inventory illustrations;

say "'An exquisite item,’ Maximus says. ‘It’ll help you tick off the hours you’ll spend in hell for your evil ways.’

You explain that the Manor is condemned anyway. ‘The Oakville Manor? I know that grand old place...’ Maximus says. He agrees to join your raiding party.[paragraph break][bold type]***Maximus the Cleric has joined your party.***[roman type]".

Beer bottle glass is scenery in Inside the Coachhouse. Understand "brown glass" or "glass" as beer bottle glass. The description of the beer bottle glass is "Beer bottles, maybe?" Before taking beer bottle glass:

say "It's shiny in the right light, but it's no loot.";

stop the action.

The map is a thing in the Adventurers' Lounge. The description of the map is "It's the route from your house to the Manor." The illustration of the map is "i_map".

The doorknob is a thing. Understand "knob" or "door knob" as the doorknob. The description of the doorknob is "Crystal or glass, beautifully cut in either case." The illustration of the doorknob is "i_doorknob".

The fork is a thing. The description of the fork is "It's only slightly tarnished, and will polish up nicely." The illustration of the fork is "i_fork".

The letter opener is a thing. The description of the letter opener is "Pretty bad-ass looking for an antique." The illustration of the letter opener is "i_letteropener".

The pocket watch is a thing. Understand "pocketwatch" or "watch" or "gleam" or "gold" as the pocket watch. The description of the pocket watch is "It's gorgeous, clam-shaped and golden." The illustration of the pocket watch is "i_pocketwatch". The pocket watch can be polished.

The white wine is a thing. The description of the white wine is "The label is hard to read under all the dust." The illustration of the white wine is "i_whitewine".

There is a magazine in Inside the Coachhouse. Understand "motion" or "flutter" or "corner" or "stack" or "tome" or "forbidden tome" or "forbidden" as a magazine. "A flutter of motion attracts your eye to something in the corner." The description of the magazine is "A magazine concerning ladies of the night. Unquestioningly valuable to many gentlemen of your acquaintance." The illustration of the magazine is "i_magazine".

Understand the command "read" as something new. Understand "read [something]" as reading. Reading is an action applying to one thing. Instead of reading the magazine, say "A good thief doesn't get high on his own supply." Instead of drinking the white wine, say "A good thief doesn't get high on his own supply."

There is a Notice of Demolition in the Portico of the Manor. Understand "paper" and "sheath" as Notice of Demolition. "A paper in a plastic sheath is stapled to the planks." Instead of taking Notice of Demolition, say "It's stapled with about a million heavy duty staples. Plus, you can read it as it is." The description of Notice of Demolition is "It’s a Notice of Demolition. Ryan overheard his mom talking to her other historical preservation friends about it, apparently there’s some kind of structural damage that makes it dangerous. Personally you think it’s more dangerous to let the cookie-cutter semi-detached monotony ooze slowly over the entire city.

The date on it indicates it’s got [if harry is joined]two days[otherwise if chris is joined]one day[otherwise if paula is joined]mere hours[otherwise]three days[end if] to live. If you don’t get to explore it it won’t be the end of the world: just the end of your boyhood dreams. "

A plank is in the Portico of the Manor. Understand "planks" or "wood" or "door" as plank. A Plank is scenery. The description of the Plank is "Yep, the planks have really blocked that door effectively."

Instead of taking the plank:

if Harry is joined:

try going north;

otherwise:

say "Nope. Your light fingers are better suited to thieving, not heaving. You're going to need help.".

Instead of pulling the plank, try taking the plank. Instead of pushing the plank, try taking the plank. Instead of taking off the plank, try taking the plank. The plank can be intact or removed. The plank is intact.

Shapes are in Inside the Manor. Shapes are scenery. Understand "furniture" or "chairs" as shapes. The description of the shapes are "You touch them and a plume of dust is raised -- dust that actually seems thicker than the sheets themselves. [if harry is in the room]Across the room, Harry yanks one off and spends a full minute rubbing his eyes and coughing. For his trouble he’s revealed a couple of unremarkable chairs.[end if]

Your thief’s instincts tell you that there’s nothing but unwanted furniture under the sheets, too old to be fashionable but not old enough to be antique."

Instead of jumping in Inside the Manor:

say "Over that hole? No thanks. You'll leave that to the jumping professionals. You could just try GO UP though."

Understand "jump in hole" or "jump over hole" or "jump across hole" as a mistake ("You could just try GO UP.")